3D-printing/OrcaSlicer
1
0
Fork 0
mirror of https://github.com/SoftFever/OrcaSlicer.git synced 2025-07-23 22:54:08 -06:00
Code Issues Projects Releases Packages Wiki Activity Actions 2

Generate GCODE

Browse source
This commit is contained in:
Alessandro Ranellucci 2011-09-03 20:47:38 +02:00
parent 74b4d8d612
commit a5ba0af7ef
6 changed files with 139 additions and 4 deletions
Download patch file Download diff file Expand all files Collapse all files

109
lib/Slic3r/Print.pm
View file

@ -1,6 +1,23 @@
package Slic3r::Print;
use Moose;
use constant X => 0;
use constant Y => 1;
has 'x_length' => (
is => 'ro',
isa => 'Slic3r::Line::Length',
required => 1,
coerce => 1,
);
has 'y_length' => (
is => 'ro',
isa => 'Slic3r::Line::Length',
required => 1,
coerce => 1,
);
has 'layers' => (
traits => ['Array'],
is => 'rw',
@ -38,4 +55,96 @@ sub extrude_perimeters {
}
}
sub export_gcode {
my $self = shift;
my ($file) = @_;
# calculate speed for gcode commands
my $travel_feed_rate = $Slic3r::travel_feed_rate * 60; # mm/min
my $print_feed_rate = $Slic3r::print_feed_rate * 60; # mm/min
my $extrusion_speed_ratio = ($Slic3r::flow_rate / $Slic3r::print_feed_rate);
# calculate number of decimals
my $dec = length((1 / $Slic3r::resolution) - 1);
# calculate X,Y shift to center print around specified origin
my @shift = (
$Slic3r::print_center->[X] - ($self->x_length * $Slic3r::resolution / 2),
$Slic3r::print_center->[Y] - ($self->y_length * $Slic3r::resolution / 2),
);
# open output gcode file
open my $fh, ">", $file
or die "Failed to open $file for writing\n";
# write start commands to file
# TODO: this must be customizable by user
print $fh "G28 ; home all axes\n";
printf $fh "M109 S%d ; wait for temperature to be reached\n", $Slic3r::temperature;
print $fh "G90 ; use absolute coordinates\n";
print $fh "G21 ; set units to millimeters\n";
if ($Slic3r::use_relative_e_distances) {
print $fh "M83 ; use relative distances for extrusion\n";
} else {
print $fh "M82 ; use absolute distances for extrusion\n";
}
# make up a subroutine to generate G1 commands
my $G1 = sub {
my ($point, $z, $extrusion_distance, $comment) = @_;
printf $fh "G1 X%.${dec}f Y%.${dec}f Z%.${dec}f",
($point->x * $Slic3r::resolution) + $shift[X],
($point->y * $Slic3r::resolution) + $shift[Y], #**
$z;
if ($extrusion_distance) {
printf $fh " F%.${dec}f E%.${dec}f",
$print_feed_rate,
($extrusion_distance * $extrusion_speed_ratio * $Slic3r::resolution);
} else {
printf $fh " F%.${dec}f", $travel_feed_rate;
}
printf $fh " ; %s", $comment if $comment;
print $fh "\n";
};
# write gcode commands layer by layer
foreach my $layer (@{ $self->layers }) {
my $z = ($layer->z * $Slic3r::resolution);
# go to layer
# TODO: retraction
printf $fh "G1 Z%.${dec}f F%.${dec}f ; move to next layer\n",
$z, $travel_feed_rate;
# extrude perimeters
foreach my $perimeter (@{ $layer->perimeters }) {
# reset extrusion distance counter
my $extrusion_distance = 0;
if (!$Slic3r::use_relative_e_distances) {
print $fh "G92 E0 ; reset extrusion distance\n";
}
# go to first point (without extruding)
$G1->($perimeter->lines->[0]->a, $z, 0, 'move to first perimeter point');
# extrude while going to next points
foreach my $line (@{ $perimeter->lines }) {
$extrusion_distance = 0 if $Slic3r::use_relative_e_distances;
$extrusion_distance += $line->a->distance_to($line->b);
$G1->($line->b, $z, $extrusion_distance, 'perimeter');
}
}
}
# write end commands to file
# TODO: this must be customizable by user
print $fh "M104 S0 ; turn off temperature\n";
print $fh "G28 X0 ; home X axis\n";
print $fh "M84 ; disable motors\n";
# close our gcode file
close $fh;
}
1;