Add the full source of BambuStudio

using version 1.0.10

deps/CGAL/CGAL.cmake

@@ -0,0 +1,31 @@
+bambustudio_add_cmake_project(
+    CGAL
+     GIT_REPOSITORY https://github.com/CGAL/cgal.git
+     GIT_TAG        caacd806dc55c61cc68adaad99f2240f00493b29 # releases/CGAL-5.3
+    # For whatever reason, this keeps downloading forever (repeats downloads if finished)
+    #URL      https://github.com/CGAL/cgal/archive/releases/CGAL-5.0.zip
+    #URL_HASH SHA256=c2b035bd078687b6d8c0fb6371a7443adcdb647856af9969532c4050cd5f48e5
+    DEPENDS dep_Boost dep_GMP dep_MPFR
+)
+
+include(GNUInstallDirs)
+
+# CGAL, for whatever reason, makes itself non-relocatable by writing the build directory into
+# CGALConfig-installation-dirs.cmake and including it in configure time.
+# If this file is not present, it will not consider the stored absolute path
+ExternalProject_Add_Step(dep_CGAL dep_CGAL_relocation_fix
+    DEPENDEES install
+
+    COMMAND ${CMAKE_COMMAND} -E remove CGALConfig-installation-dirs.cmake
+    WORKING_DIRECTORY "${DESTDIR}/usr/local/${CMAKE_INSTALL_LIBDIR}/cmake/CGAL"
+)
+
+# Again, for whatever reason, CGAL thinks that its version is not relevant if
+# configured as a header only library. Fixing it by placing a cmake version file
+# besides the installed config file.
+ExternalProject_Add_Step(dep_CGAL dep_CGAL_version_fix
+    DEPENDEES install
+
+    COMMAND ${CMAKE_COMMAND} -E copy cgal/CGALConfigVersion.cmake "${DESTDIR}/usr/local/${CMAKE_INSTALL_LIBDIR}/cmake/CGAL/CGALConfigVersion.cmake"
+    WORKING_DIRECTORY "${CMAKE_CURRENT_LIST_DIR}"
+)

deps/CGAL/cgal/CGALConfigVersion.cmake

@@ -0,0 +1,25 @@
+# This is a basic version file for the Config-mode of find_package().
+# It is used by write_basic_package_version_file() as input file for configure_file()
+# to create a version-file which can be installed along a config.cmake file.
+#
+# The created file sets PACKAGE_VERSION_EXACT if the current version string and
+# the requested version string are exactly the same and it sets
+# PACKAGE_VERSION_COMPATIBLE if the current version is >= requested version.
+# The variable CVF_VERSION must be set before calling configure_file().
+
+set(PACKAGE_VERSION "5.0.0")
+
+if(PACKAGE_VERSION VERSION_LESS PACKAGE_FIND_VERSION)
+  set(PACKAGE_VERSION_COMPATIBLE FALSE)
+else()
+  set(PACKAGE_VERSION_COMPATIBLE TRUE)
+  if(PACKAGE_FIND_VERSION STREQUAL PACKAGE_VERSION)
+    set(PACKAGE_VERSION_EXACT TRUE)
+  endif()
+endif()
+
+
+# if the installed project requested no architecture check, don't perform the check
+if("FALSE")
+  return()
+endif()